home | O'Reilly's CD bookshelfs | FreeBSD | Linux | Cisco | Cisco Exam  

Book HomeLearning Perl, 3rd EditionSearch this book

9.7. The split Operator

Another operator that uses regular expressions is split, which breaks up a string according to a separator. This is useful for tab-separated data, or colon-separated, whitespace-separated, or anything-separated data, really.[211] So long as you can specify the separator with a regular expression (and generally, it's a simple regular expression), you can use split. It looks like this:

[211]Except "comma-separated values," normally called CSV files. Those are a pain to do with split; you're better off getting the Text::CSV module from CPAN.

@fields = split /separator/, $string;

The split operator[212] drags the pattern through a string and returns a list of fields (substrings) that were separated by the separators. Whenever the pattern matches, that's the end of one field and the start of the next. So, anything that matches the pattern will never show up in the returned fields. Here's a typical split pattern, splitting on colons:

[212]It's an operator, even though it acts a lot like a function, and everyone generally calls it a function. But the technical details of the difference are beyond the scope of this book.

@fields = split /:/, "abc:def:g:h";  # gives ("abc", "def", "g", "h")

You could even have an empty field, if there were two delimiters together:

@fields = split /:/, "abc:def::g:h";  # gives ("abc", "def", "", "g", "h")

Here's a rule that seems odd at first, but it rarely causes problems: Leading empty fields are always returned, but trailing empty fields are discarded:[213]

[213]This is merely the default. It's this way for efficiency. If you worry about losing trailing empty fields, use -1 as a third argument to split and they'll be kept; see the perlfunc manpage.

@fields = split /:/, ":::a:b:c:::";  # gives ("", "", "", "a", "b", "c")

It's also common to split on whitespace, using /\s+/ as the pattern. Under that pattern, all whitespace runs are equivalent to a single space:

my $some_input = "This  is a \t        test.\n";
my @args = split /\s+/, $some_input;  # ("This", "is", "a", "test.")

The default for split is to break up $_ on whitespace:

my @fields = split;  # like split /\s+/, $_;

This is almost the same as using /\s+/ as the pattern, except that a leading empty field is suppressed -- so, if the line starts with whitespace, you won't see an empty field at the start of the list. (If you'd like to get the same behavior when splitting another string on whitespace, just use a single space in place of the pattern: split ' ', $other_string. Using a space instead of the pattern is a special kind of split.)

Generally, the patterns used for split are as simple as the ones you see here. But if the pattern becomes more complex, be sure to avoid using memory parentheses in the pattern; see the perlfunc manpage for more information.[214]

[214]And you might want to check out the nonmemory grouping-only parenthesis notation as well, in the perlre manpage.

Library Navigation Links

Copyright © 2002 O'Reilly & Associates. All rights reserved.