Answer to Chapter 10 Exercise (Learning Perl, 3rd Edition)

A.9. Answer to Chapter 10 Exercise

Here's one way to do it:
```
my $secret = int(1 + rand 100);
# This next line may be un-commented during debugging
# print "Don't tell anyone, but the secret number is $secret.\n";

while (1) {
  print "Please enter a guess from 1 to 100: ";
  chomp(my $guess = <STDIN>);
  if ($guess =~ /quit|exit|^\s*$/i) {
    print "Sorry you gave up. The number was $secret.\n";
    last;
  } elsif ($guess < $secret) {
    print "Too small. Try again!\n";
  } elsif ($guess == $secret) {
    print "That was it!\n";
    last;
  } else {
    print "Too large. Try again!\n";
  }
}
```
The first line picks out our secret number from 1 to 100. Here's how it works. First, rand is Perl's random number function, so rand 100 gives us a random number in the range from zero up to (but not including) 100. That is, the largest possible value of that expression is something like 99.999.[397] Adding one gives a number from 1 to 100.999, then the int function truncates that, giving a result from 1 to 100, as we needed.

[397]The actual largest possible value depends upon your system; see http://www.cpan.org/doc/FMTEYEWTK/random if you really need to know.

The commented-out line can be helpful during development and debugging, or if you like to cheat. The main body of this program is the infinite while loop. That will keep asking for guesses until we execute last.

It's important that we test the possible strings before the numbers. If we didn't, do you see what would happen when the user types quit? That would be interpreted as a number (probably giving a warning message, if warnings were turned on), and since the value as a number would be zero, the poor user would get the message that their guess was too small. We might never get to the string tests, in that case.

Another way to make the infinite loop here would be to use a naked block with redo. It's no more or less efficient; merely another way to write it. Generally, if you expect to mostly loop, it's good to write while, since that loops by default. If looping will be the exception, a naked block may be a better choice.